MÉDIASE e MÉDIASES no Excel: Como usá-las?
Quer aprender a usar as funções MÉDIASE e MÉDIASES no Excel? Então este post é para você!
A média é um dos cálculos mais utilizados dentro da área de estatística. Você pode utilizá-la para obter a média das notas de um aluno, a média de vendas anual, a média de público pagante, entre outros cenários comuns.
Calcular a média no Excel é uma tarefa muito simples, já que podemos utilizar a função MÉDIA para retornar a média de um intervalo de células. Mas o que fazer o quando precisamos calcular a média com base em um ou mais critérios? Por exemplo, obter a média das vendas de carros de uma determinada marca, a média de vendas realizadas em uma determinada região ou a média de vendas de um determinado vendedor?
Neste caso, podemos contar com as funções MÉDIASE e MÉDIASES. Neste post separamos um compilado sobre o uso dessas duas funções para que você possa conhecê-las e utilizá-las em suas planilhas. Confira!
- O que é MÉDIASE no Excel?
- Como usar a função MÉDIASE Excel?
- Detalhes que você deve considerar
- Função MÉDIASES para dois ou mais critérios
- Detalhes que você deve considerar
O que é MÉDIASE no Excel?
MÉDIASE é uma função de estatística do Excel, que calcula a média de um determinado intervalo de células por um critério específico. Basicamente, a função MÉDIASE calcula a tendência central, que é a localização do centro de um grupo de números numa distribuição estatística.
Por exemplo, suponha que temos uma tabela com as vendas de alguns vendedores e precisamos saber a média de vendas de um determinado vendedor. Usando a função Excel MÉDIASE, podemos calcular a média de todas as vendas realizadas por um vendedor específico. Em outras palavras, podemos calcular a média das vendas tendo como condição o nome do vendedor.
Como usar a função MÉDIASE Excel?
A função MÉDIASE foi inserida no Excel 2007 e sua sintaxe é:
=MÉDIASE (intervalo, critérios, [intervalo_média])
Onde:
- intervalo: (argumento obrigatório). Representa o intervalo de uma ou mais células que se deseja calcular a média. O argumento pode incluir números ou nomes, matrizes ou referências que contenham números.
- critérios: (argumento obrigatório). Representa os critérios que determinam como será calculada a média da célula. Os critérios podem estar na forma de uma expressão, número, referência de célula ou texto que define quais células serão calculadas em média. Por exemplo: 5, “<12”, “Laranjas” ou A3.
- intervalo_média: (argumento opcional). Representa o conjunto real de células que desejamos calcular a média. Se este argumento for omitido, a função usará o intervalo fornecido no argumento intervalo.
Para aprender a utilizar a função MÉDIASE no Excel, confira os exemplos abaixo:
Exemplo 1: Calculando a Média das Vendas de um vendedor
Neste primeiro exemplo temos uma tabela com os registros de vendas de alguns vendedores e desejamos obter a média das vendas do vendedor André.
Neste caso, basta utilizar a seguinte fórmula:
=MÉDIASE(A2:A10;"André";B2:B10)
Além do nome inserido diretamente na fórmula, você também pode utilizar uma referência de célula para o argumento critérios. Então, suponha que o nome do vendedor esteja na célula E2. Neste caso, a fórmula ficará:
=MÉDIASE(A2:A10;E2;B2:B10)
Exemplo 2: MÉDIASE com Datas
Semelhante aos números, você pode usar datas como critérios para a função MÉDIASE. No exemplo abaixo, temos uma tabela contendo as vendas de alguns vendedores com as datas de cada venda e precisamos obter a média das vendas que foram realizadas antes de 08/02/2024. Neste caso, a fórmula ficará:
=MÉDIASE(C2:C10;"<08/02/2024";B2:B10)
Alguns outros exemplos de uso da função MÉDIASE com datas são:
- Para garantir que a data seja inserida no formato que o Excel entende, você pode usar a função DATA concatenada com o operador lógico:
=MÉDIASE(C2:C10;"<"&DATA(2024;2;8);B2:B10)
- Para calcular a média das vendas realizadas até a data de hoje, use a função HOJE nos critérios:
=MÉDIASE(C2:C10;"<"&HOJE();B2:B10)
- Para calcular a média das vendas realizadas antes de uma data que está inserida em uma célula (por exemplo, H1):
=MÉDIASE(C2:C10;"<"&H1;B2:B10)
Exemplo 3: MÉDIASE com correspondência parcial
Para calcular a média das células com base na correspondência parcial, use caracteres curinga nos critérios da sua fórmula MÉDIASE:
- Um ponto de interrogação (?) para corresponder a qualquer caractere.
- Um asterisco (*) para corresponder a qualquer sequência de caracteres.
No exemplo abaixo temos uma tabela contendo algumas frutas e suas respectivas vendas. Neste caso, precisamos calcular as vendas do produto Uva, porém, observe que temos diferentes tipos de uva (Uva, Uva Niágara e Uva Rubi).
Deste modo, para calcular a média das vendas dos 3 tipos de Uva, use a fórmula abaixo:
=MÉDIASE(A2:A12;"*"&D4&"*";B2:B12)
Exemplo 4: Como calcular a média no Excel excluindo certas células
Para excluir determinadas células da média, use o operador lógico “diferente de” (<>).
Por exemplo, para calcular a média das vendas, excluindo o produto Uva, utilize a fórmula abaixo:
=MÉDIASE(A2:A12;"<>"&D4;B2:B12)
Alguns outros exemplos de uso da função MÉDIASE com exclusão de valores são:
- Para calcular a média de todos os itens excluindo qualquer tipo de “Uva”, use “diferente de” junto com um curinga:
=MÉDIASE(A2:A12;"<>*Uva*";B2:B12)
- Para calcular a média de todos os valores em B2:B12, exceto zeros, use a fórmula:
=AVERAGEIF(B3:B15, "<>0")
Detalhes que você deve considerar
- Todas as células vazias são ignoradas pela fórmula para o argumento [intervalo_média].
- A função retornará o erro #DIV/0! se os critérios errados forem fornecidos.
- Os valores lógicos VERDADEIRO e FALSO são tratados como 1 e 0 respectivamente.
- Valores zero estão incluídos na média.
- Se uma célula de critério estiver vazia, ela será tratada como um valor zero (0).
Função MÉDIASES para dois ou mais critérios
Conforme demonstrado acima, para calcular a média das células que atendem a uma determinada condição, a função MÉDIASE é útil. Por outro lado, para encontrar uma média com vários critérios, a função a ser utilizada é a MÉDIASES.
A função Excel MÉDIASES calcula a média aritmética de todas as células em um intervalo que atende aos critérios especificados.
A sintaxe da função é a seguinte:
=MÉDIASES(intervalo_média, intervalo_critérios1, critérios1, [intervalo_critérios2, critérios2], …)
Onde:
- intervalo_média: (argumento obrigatório). Representa o intervalo de células que será calculada a média.
- intervalo_de_critérios1, intervalo_de_critérios2, …: Representa os intervalos a serem testados em relação aos critérios correspondentes.
- critério1, critério2, … determinam quais células devem ser calculadas como média. Os critérios podem ser fornecidos na forma de um número, expressão lógica, valor de texto ou referência de célula.
Critérios_intervalo1 / critérios1 são obrigatórios, os subsequentes são opcionais. 1 a 127 pares de intervalo/critério podem ser usados em uma fórmula.
Para melhor compreensão, confira abaixo alguns exemplos de uso da função MÉDIASES.
Exemplo 1: Calculando a média para dois critérios
Neste exemplo, temos uma tabela contendo alguns produtos, a região onde houve a venda do produto e o valor das vendas. Neste caso, precisamos calcular a média das vendas do produto Maçã realizadas na região Sul, ou seja, temos dois critérios que são: Produto e Região.
Para isto, utilizaremos a seguinte fórmula:
=MÉDIASES(C2:C13;A2:A13;F3;B2:B13;F4)
No exemplo acima utilizamos referências de células para os critérios. No entanto, você também poderá especificar os critérios, inserindo os valores diretamente na fórmula, dentro de aspas duplas. Veja o exemplo abaixo:
=MÉDIASES(C2:C13;A2:A13;"Maçã";B2:B13;"Sul")
Exemplo 2: MÉDIASES com operadores lógicos
A função MÉDIASES também permite o uso de operadores lógicos nos critérios. No exemplo abaixo, precisamos calcular a média das vendas do produto Maçã, porém apenas as vendas maiores do que R$160,00. Para isto, utilizaremos a seguinte fórmula:
=MÉDIASES(B2:B13;A2:A13;E3;B2:B13;">"&E4)
Exemplo 3: MÉDIASES com Datas
Os valores em formato de data também podem ser utilizados como critério na função MÉDIASES. Para melhor compreensão, observe o exemplo abaixo no qual temos os registros de vendas de alguns produtos, incluindo a data da venda. Neste caso, precisamos calcular a média das vendas para o produto Maçã, porém, apenas as vendas realizadas a partir de 07/02/2024. Para isto, utilizaremos a seguinte fórmula:
=MÉDIASES(C2:C13;A2:A13;F3;B2:B13;">="&F4)
Exemplo 4: MÉDIASES com correspondência parcial
Para calcular a média das células com base na correspondência parcial de texto, use caracteres curinga nos critérios – um ponto de interrogação (?) para corresponder a qualquer caractere único ou um asterisco (*) para corresponder a qualquer número de caracteres.
Na imagem abaixo, desejamos calcular a média do produto Maçã cujas vendas foram realizadas a partir de 07/02/2024. No entanto, observe que temos diferentes tipos de registros para o produto Maçã, ou seja, temos Maçã Gala, Maçã Red e apenas Maçã. Neste caso, podemos utilizar o caractere curinga (* asterisco) com o critério para que o Excel considere todos os registro que apresenta a palavra Maçã.
=MÉDIASES(C2:C13;A2:A13;"*"&F3&"*";B2:B13;">="&F4)
Detalhes que você deve considerar
- No argumento intervalo_média, células vazias, valores lógicos VERDADEIRO/FALSO e valores de texto são ignorados. Valores zero estão incluídos.
- Se o critério for uma célula vazia, ele será tratado como um valor zero.
- Se intervalo_média não contiver um único valor numérico, o Excel retornará o erro #DIV/0!.
- Se nenhuma célula atender a todos os critérios especificados, o erro #DIV/0! será retornado.
- Os critérios da função MÉDIASES podem ser aplicados ao mesmo intervalo ou a intervalos diferentes.
- Cada intervalo_de_critérios deve ter o mesmo tamanho e formato que intervalo_média , caso contrário, o Excel retornará o erro #VALOR!.
Baixe aqui a planilha com os exemplos apresentados neste post.
Confira também as seguintes dicas de Excel:
E então, o que achou dos exemplos de uso da função MÉDIASE e função MÉDIASES no Excel? Caso tenha ficado com alguma dúvida, basta deixar seu comentário abaixo!