Função SEERRO no Excel – Do Básico ao Avançado

janeiro 11, 2019dezembro 8, 2021 admin 0 comentários

Ainda não sabe como usar a função SEERRO no Excel? Então esse tutorial é para você!

A função SEERRO do Excel é uma das melhores opções quando se pretende tratar erros em fórmulas. Se você ainda não conhece os principais erros do Excel, recomendamos a leitura dos artigos: #DIV/0!, #N/D, #NOME?, #NÚLO!, #NÚM!, #REF! e #VALOR!.

E então, pronto para aprender a deixar suas planilhas livres de erros? Conheça a seguir os detalhes da função SEERRO.

SERRO – Sintaxe e usos básicos?
Coisas a saber sobre SEERRO no Excel
Exemplos de uso da função
SEERRO vs ÉERROS
SEERRO vs SENÃODISP
Práticas recomendadas para usar o SEERRO no Excel

Função SEERRO no Excel – Sintaxe e usos básicos

A função SEERRO no Excel foi criada para interceptar e gerenciar erros em fórmulas e cálculos. Basicamente essa função verifica uma fórmula e, se ela resultar em um erro, retorna outro valor especificado por você; caso contrário, retorna o resultado da fórmula.

A sintaxe da função SEERRO é a seguinte:

=SEERRO(valor;valor_se_erro)

Onde:

Valor: (campo obrigatório) – o que verificar se há erros. Pode ser uma fórmula, expressão, valor ou referência de célula.
Valor_se_erro: (campo obrigatório) – o que retornar se um erro for encontrado. Pode ser uma string vazia (célula em branco), mensagem de texto, valor numérico, outra fórmula ou cálculo.

Por exemplo, ao dividir duas colunas de números, você pode obter vários erros diferentes se uma das colunas contiver células vazias, zeros ou texto.

Para evitar que isso ocorra, use a função SEERRO para capturar e manipular erros da maneira desejada.

Célula em branco em caso se erro

Forneça uma string vazia (“”) ao argumento valor_se_erro para retornar uma célula em branco se um erro for encontrado:

=SEERRO(A2/B2;"")

Exibir mensagem em caso de erro

Outra opção é exibir sua própria mensagem em vez do erro padrão do Excel:

=SEERRO(A2/B2;"Erro de cálculo")

Coisas que você precisa saber sobre a função SEERRO do Excel

A função SEERRO no Excel lida com todos os tipos de erro, incluindo #DIV/0!, #N/D, #NOME?, #NÚLO!, #NÚM!, #REF! e #VALOR!.
Dependendo do conteúdo do argumento valor_se_erro, a função SEERRO pode substituir erros com sua mensagem de texto, número, data ou valor lógico, o resultado de uma outra fórmula, ou uma string vazia (célula em branco).
Se o argumento valor for uma célula em branco, será tratado como uma string vazia (“”), mas não será um erro.
A função SEEERRO foi introduzida no Excel 2007 e está disponível em todas as versões posteriores.
Para interceptar erros no Excel 2003 e versões anteriores, use a função ÉERROS em combinação com a função SE, conforme mostrado neste exemplo.

Está gostando do artigo? Compartilhe com seus amigos no Facebook

Exemplos de uso da função SEERRO

Os exemplos a seguir mostram como usar a função SEERRO no Excel em combinação com outras funções para realizar tarefas mais complexas.

SEERRO com PROCV no Excel

Provavelmente um dos usos mais comuns da função SEERRO é dizer aos usuários que o valor que eles estão procurando não existe no conjunto de dados. Para isso, podemos usar a função SEERRO com a função PROCV da seguinte maneira:

=SEERRO(PROCV(…);"Não encontrado")

Se o valor de pesquisa não estiver na tabela que você está procurando, a função PROCV irá retornar o erro #N/D. Veja o exemplo abaixo onde estamos fazendo uma busca na lista, porém como o campo Produto está vazio, o Excel nos retorna o erro #N/D.

Para evitar que isso ocorra, podemos usar a função SEERRO da seguinte maneira:

Dica: Confira aqui outros exemplos de uso da Função SEERRO com PROCV.

Funções SEERRO aninhadas para fazer PROCV sequenciais no Excel

Em situações em que você precisa executar vários PROCVs com base no sucesso ou falha do PROCV anterior, é possível incluir duas ou mais funções SEERRO.

Por exemplo: Suponha que você tenha relatórios de vendas das filiais de sua empresa e queira obter um valor para um determinado Código de Venda. Em uma planilha você poderá fazer a pesquisa em 3 planilhas diferentes (Filial 1, Filial 2 e Filial 3).

Para isso, usaremos a seguinte fórmula:

=SEERRO(PROCV(A2;'Filial 1'!A2:B5;2;0);SEERRO(PROCV(A2;'Filial 2'!A2:B5;2;0);SEERRO(PROCV(A2;'Filial 3'!A2:B5;2;0);"Não encontrado")))

Como resultado teremos:

SEERRO em fórmulas de matriz

Como você provavelmente já sabe, as fórmulas de matriz no Excel destinam-se a executar vários cálculos dentro de uma única fórmula. Se você fornecer uma fórmula de matriz ou expressão que resulte em uma matriz no argumento de valor da função SEERRO, ela retornará uma matriz de valores para cada célula no intervalo especificado. O exemplo abaixo mostra os detalhes.

Digamos que você tenha Total na coluna B e Preço na coluna C e queira calcular a Quantidade total. Isso pode ser feito usando a seguinte fórmula de matriz, que divide cada célula no intervalo B2:B4 pela célula correspondente do intervalo C2:C4 e, em seguida, adiciona os resultados:

=SOMA(B2:B4/C2:C4)

A fórmula funciona bem, desde que o intervalo do divisor não tenha zeros ou células vazias. Se houver pelo menos um valor 0 ou uma célula em branco, o erro #DIV/0! é retornado:

Para corrigir esse erro, basta fazer a divisão dentro da função SEERRO:

=SOMA(SEERRO(B2:B4/C2:C4;0))

Basicamente, o que a fórmula faz é dividir um valor na coluna B por um valor na coluna C em cada linha (100/2, 200/5 e 0/0) e retornar a matriz de resultados {50; 40; #DIV/0!}. A função SEERRO pega todos os erros #DIV/0! e os substitui por zeros. E então, a função SOMA soma os valores na matriz resultante {50; 40; 0} e produz o resultado final (50 + 40 = 90).

Nota: Lembre-se de que as fórmulas de matriz devem ser preenchidas pressionando o atalho Ctrl+Shift+Enter.

SEERRO vs ÉERROS

Agora que você sabe como é fácil usar a função SEERRO no Excel, talvez esteja se perguntando por que algumas pessoas ainda se inclinam a usar a combinação SE e ÉERRO.

Existe alguma vantagem em comparação com a SEERRO? Nenhuma.

Na época do Excel 2003 e versões anteriores, quando a função SEERRO não existia, usar as funções SE e ÉERRO era a única maneira possível de interceptar erros. Já no Excel 2007 e posterior, esta é apenas uma maneira um pouco mais complexa para obter o mesmo resultado.

Por exemplo, para capturar erros de PROCV, você pode usar uma das fórmulas abaixo.

No Excel 2007 até versões mais recentes:

SEERRO(PROCV(… );"Não encontrado")

Em todas as versões do Excel:

SE(ÉERRO(PROCV(…));"Não encontrado";PROCV(…)

Note que na fórmula SE ÉERRO PROCV, você precisa fazer o PROCV duas vezes. Em linguagem simples, a fórmula pode ser lida da seguinte forma: Se PROCV resultar em erro, retorne “Não encontrado”, caso contrário, exiba o resultado do PROCV.

E aqui está um exemplo real de uma fórmula do Excel onde usamos SE ÉERRO PROCV:

SEERRO vs SENÃODISP

Introduzida no Excel 2013, a função SENÃODISP é mais uma função para verificar erros em uma fórmula. Sua sintaxe é semelhante à da função SEERRO:

=SENÃODISP(valor;valor_se_na)

Mas de que maneira a função SENÃODISP é diferente da SEEERO? Basicamente, a função SENÃODISP detecta apenas erros #N/D, enquanto a SEERRO trata todos os tipos de erros.

Em quais situações você pode querer usar a SENÃODISP? Quando não é aconselhável disfarçar todos os erros. Por exemplo, ao trabalhar com dados importantes ou sensíveis, você pode querer ser alertado sobre possíveis falhas em seu conjunto de dados, e mensagens de erro padrão do Excel com o símbolo “#” podem ser indicadores visuais comuns.

Vamos ver como você pode criar uma fórmula que exiba a mensagem “Não encontrado” em vez do erro #N/D, que aparece quando o valor de pesquisa não está presente no conjunto de dados, mas chama a atenção para outros erros do Excel.

Suponha-se que você queira puxar a Qtd. da tabela de consulta para a tabela de resumo, como mostrado na imagem de tela abaixo. Usando as funções SEERRO e PROCV, a fórmula produziria um resultado esteticamente agradável, porém tecnicamente incorreto porque os limões existem na tabela de pesquisa:

Por outro lado, para tratar o erro #N/D, mas exibir o erro #DIV/0, basta usar a função SENÃODISP no Excel 2013 ou versão superior conforme exemplo abaixo:

=SENÃODISP(PROCV(F2;$A$2:$D$5;4;FALSO);"Não encontrado")

Para o Excel 2010 ou versão inferiores você pode usar a seguinte fórmula:

=SE(SENÃODISP(PROCV(F2;$A$2:$D$5;4;FALSO));"Não encontrado";PROCV(F2;$A$2:$D$5;4;FALSO))

A sintaxe das fórmulas SENÃODISP PROCV e SE SENÃODISP PROCV são semelhantes às da SEERRP PROCV e SE ÉERRO PROCV mostradas anteriormente.

Conforme mostrado na imagem abaixo, a fórmula SENÃODISP PROCV retorna “Não encontrado” somente para o item que não está presente na tabela de pesquisa (Pêssego). Para os limões, mostra o erro #DIV/0! indicando que nossa tabela de pesquisa contém um erro de divisão por zero:

Práticas recomendadas para usar o SEERRO no Excel

Se você chegou até aqui, então já sabe que a função SEERRO é a maneira mais fácil de capturar erros no Excel e mascará-los com células em branco, valores zero ou mensagens personalizadas próprias. No entanto, isso não significa que você deve quebrar cada fórmula com tratamento de erros. As seguintes recomendações podem ajudá-lo a decidir quando usar ou não a função SEERRO:

Não intercepte erros sem um motivo.
Envolva a menor parte possível de uma fórmula na função SEERRO.
Para lidar apenas com erros específicos, use uma função de tratamento de erros com um escopo menor:

SENÃODISP ou SE SENÃODISP para capturar apenas erros #N/D.
ÉERRO para pegar todos os erros, exceto #N/D.

Leia também:

E então, o que achou da dica sobre a função SEERRO no Excel? Deixe o seu comentário abaixo, gostaríamos muito de conhecer a sua opinião! Para conferir mais dicas de Excel, continue acompanhando o Excel Easy!