Como Contar Caracteres no Excel

dezembro 2, 2018setembro 13, 2023 admin 0 comentários

Quer aprender a contar caracteres no Excel? Então este post é para você!

Quando se trabalha com as planilhas do Excel, muitas vezes é necessário contar o número de caracteres em células únicas ou intervalo de células. Esses caracteres podem ser numéricos, textos, letras ou na forma de um caractere especial.

Neste artigo você vai aprender algumas opções para a contagem de caracteres no Excel para aplicar em diferentes cenários. Se interessou pelo assunto? Então confira os detalhes a seguir!

Se preferir, você poderá navegar pelo tópico de seu interesse:

Como contar caracteres em uma célula?
Contagem de caracteres em um intervalo de células
Como contar caracteres específicos em uma célula
Como contar palavras ou combinação de caracteres
Como contar caracteres específicos em um intervalo
Como contar combinação de caracteres em um intervalo

Como contar caracteres em uma célula?

A maioria dos usuários de Excel geralmente precisam obter apenas a quantidade de caracteres em uma célula. Para descobrir quantos caracteres existem em uma célula do Excel, basta utilizar a função NÚM.CARACT.

A função NÚM.CARACT realiza a contagem de todos os caracteres em uma célula e retorna um valor com a quantidade de caracteres existentes. A função possui apenas um argumento, que é obviamente obrigatório:

=NÚM.CARACT(texto)

Onde:

texto: é a cadeia de texto para a qual você deseja contar o número de caracteres.

Para melhor compressão, observe o exemplo abaixo onde estamos contando a quantidade de caracteres em cada célula da coluna A.

Conforme é possível observar no exemplo acima, função NÚM.CARACT conta absolutamente todos os caracteres em uma célula, incluindo letras, números, sinais de pontuação, símbolos especiais e todos os espaços (à esquerda, à direita e espaços entre palavras).

Contagem de caracteres em um intervalo de células

Para obter o total de caracteres em um intervalo de células do Excel, você pode usar a função NÚM.CARACT com a função SOMARPRODUTO.

Para melhor compreensão, observe o exemplo abaixo onde estamos realizamos a contagem de caracteres do intervalo A2:A6.

=SOMARPRODUTO(NÚM.CARACT(A2:A6))

A lógica é muito simples. A função NÚM.CARACT calcula a quantidade de caracteres para cada célula individual no intervalo especificado e retorna uma matriz de números. E então, a função SOMARPRODUTO soma esses números e retorna a contagem total de caracteres.

Leitura recomendada: Função SOMARPRODUTO no Excel: Como usar?

Outra maneira de contar todos os caracteres em um intervalo é usar a função NÚM.CARACT com a função SOMA. Veja o exemplo abaixo:

=SOMA(NÚM.CARACT(A2:A6))

Importante: Ao contrário de SOMARPRODUTO, a função SOMA não processa matrizes por padrão, então você precisa pressionar Ctrl + Shift + Enter para transformá-lo em uma fórmula de matriz no Excel 2019 e versões anteriores. No Excel 365 e 2021, funciona como uma fórmula regular devido ao suporte integrado para matrizes dinâmicas.

Como contar caracteres específicos em uma célula

Para saber quantas vezes um determinado caractere aparece em uma célula, podemos utilizar uma fórmula combinando a função NÚM.CARACT com a função SUBSTITUIR. A fórmula é organizada da seguinte maneira:

NÚM.CARACT(célula)-NÚM.CARACT(SUBSTITUIR(célula;caractere;""))

Para melhor compressão, veja o exemplo abaixo onde estamos obtendo a contagem de caracteres específico dentro de cada célula da coluna A. Neste caso a fórmula será:

=NÚM.CARACT(A2)-NÚM.CARACT(SUBSTITUIR(A2;B2;""))

Importante: A função SUBSTITUIR é uma função que diferencia maiúsculas de minúsculas e, portanto, a fórmula acima trata letras maiúsculas e minúsculas como caracteres diferentes. Por exemplo, a célula A2 da imagem acima contém 5 ocorrências de “a” e 2 ocorrências de “A”. A fórmula contou apenas o “A” maiúsculo e retornou 2 como resultado.

Por outro lado, se você precisa contar a quantidade de caráteres específicos em uma célula, mas não deseja diferenciar letras maiúsculas de minúsculas, então basta incluir a função MAIÚSCULA na fórmula para converter uma determinada letra em maiúscula antes de executar a substituição.

Deste modo, independente da letra ser maiúscula ou minúscula, o Excel retornará a quantidade presenta na célula. Confira o exemplo abaixo:

=NÚM.CARACT(A2)-NÚM.CARACT(SUBSTITUIR(MAIÚSCULA(A2);MAIÚSCULA(B2);""))

Como contar palavras ou combinação de caracteres

Se você deseja saber quantas vezes uma determinada combinação de caracteres ou palavras aparece em uma determinada célula, então basta dividir a contagem de caracteres pelo comprimento da combinação desejada. Confira o exemplo abaixo:

Fórmula com distinção entre maiúsculas e minúsculas:

=(NÚM.CARACT(A2)-NÚM.CARACT(SUBSTITUIR(A2;B2;"")))/NÚM.CARACT(B2)

Fórmula que não diferencia maiúsculas de minúsculas:

=(NÚM.CARACT(A2)-NÚM.CARACT(SUBSTITUIR(MAIÚSCULA(A2);MAIÚSCULA(B2);"")))/NÚM.CARACT(B2)

Como contar caracteres específicos em um intervalo

Nos exemplos anteriores mostramos como você pode contar caracteres específicos em uma célula no Excel. No entanto, se você deseja contar caracteres específicos em um intervalo de células, basta incluir a função SOMARPRODUTO para que a fórmula seja capaz de lidar com matrizes. Veja o exemplo abaixo:

SOMARPRODUTO(NÚM.CARACT(intervalo)-NÚM.CARACT(SUBSTITUIR(intervalo;caractere;"")))

Por exemplo, para saber quantas vezes o caractere de C2 aparece no intervalo A3:A6, a fórmula será:

=SOMARPRODUTO(NÚM.CARACT(A2:A6)-NÚM.CARACT(SUBSTITUIR(A2:A6;C2;"")))

Você também poderá utilizar a função SOMA no lugar da função SOMARPRODUTO sendo neste caso, necessário finalizar a fórmula com Ctrl + Alt + Del. A função ficará conforme exemplo abaixo:

=SOMA(NÚM.CARACT(A2:A6)-NÚM.CARACT(SUBSTITUIR(A2:A6;C2;"")))

Conforme mencionado anteriormente, a função SUBSTITUIR é uma função que diferencia maiúsculas de minúsculas e, portanto, a fórmula acima trata letras maiúsculas e minúsculas como caracteres diferentes. Por outro lado, se você precisa contar letras específicas em um intervalo de células sem diferenciar maiúsculas e minúsculas, então basta utilizar a fórmula abaixo:

=SOMARPRODUTO(NÚM.CARACT(A2:A6)-NÚM.CARACT(SUBSTITUIR(MAIÚSCULA(A2:A6);MAIÚSCULA(C2);"")))

Se preferir utilizar a função SOMA no lugar da função SOMARPRODUTO, então a fórmula ficará conforme exemplo abaixo:

=SOMARPRODUTO(NÚM.CARACT(A2:A6)-NÚM.CARACT(SUBSTITUIR(MAIÚSCULA(A2:A6);MAIÚSCULA(C2);"")))

Como contar combinação de caracteres em um intervalo

Para contar o número de ocorrências de determinado texto em um intervalo, use a seguinte fórmula:

SOMARPRODUTO((NÚM.CARACT(intervalo) - NÚM.CARACT(SUBSTITUIR( intervalo; texto ;""))) /NÚM.CARACT(texto))

Por exemplo, para contar o número de vezes que a palavra “Avenida” aparece no intervalo A3:A6, a fórmula será:

=SOMARPRODUTO(NÚM.CARACT(A2:A6)-NÚM.CARACT(SUBSTITUIR(A2:A6;C2;"")))/NÚM.CARACT(C2)

Confira também as seguintes dicas de Excel:

E então, o que achou da dica sobre como contar caracteres no Excel? Deixe o seu comentário abaixo, gostaríamos muito de conhecer a sua opinião! Para conferir mais dicas de Excel, continue acompanhando o Excel Easy!