10 Exemplos de PROCV Para Usuários Iniciantes e Avançados

junho 9, 2018agosto 13, 2020 admin 0 comentários

Está procurando por exemplos de PROCV no Excel para dominar essa função de vez? Então você está no lugar certo!

Há quem diga que a função PROCV é tão importante que se você não souber utilizá-la, então é melhor nem listar o Excel como uma das áreas fortes do seu currículo.

Aqui no site já escrevemos um artigo mostrando como você pode aprender a função PROCV no Excel em 2 minutos. Contudo, hoje mostraremos 10 exemplos de PROCV para reforçar ainda mais o seu aprendizado, seja você um usuário iniciante ou avançado.

Se interessou? Então confira os detalhes a seguir.

10 Exemplos de PROCV no Excel (Básico e Avançado)

Já está interessado(a) no que vem por aí? Então compartilhe com sua rede de amigos para que mais pessoas possam conhecer os melhores exemplos de PROCV no Excel:

Facebook

Twitter

LinkedIn

Exemplo 1 – Encontrando a Nota de Matemática de um aluno

No primeiro exemplo de PROCV abaixo, temos uma lista com nomes de alunos na coluna A e notas de diferentes matérias nas colunas B a E.

Agora vamos usar a função PROCV para ver o que ela faz melhor. Dos dados acima, precisamos saber quanto Bianca tirou em Matemática.

Abaixo está a fórmula de PROCV que retornará a pontuação de matemática de Bianca:

=PROCV(“Bianca”;$A$3:$E$10;2;0)

A fórmula acima possui quatro argumentos:

“Bianca”: – este é o valor que estamos pesquisando.
$A$3:$E$10 – este é o intervalo de células em que estamos procurando. Lembre-se de que o Excel procura o valor de pesquisa na coluna mais à esquerda. Neste exemplo, ele procuraria o nome Bianca em A3:A10 (que é a coluna mais à esquerda da matriz especificada).
2 – Uma vez que a função aponte o nome de Bianca, ela irá para a segunda coluna da matriz e retornará o valor na mesma linha de Bianca. O valor 2 aqui indica que estamos procurando a pontuação da segunda coluna da matriz especificada.
0 – diz à função PROCV para procurar apenas correspondências exatas.

Veja abaixo como a função PROCV funciona neste exemplo:

Primeiro, ela procura o valor “Bianca” na coluna mais à esquerda. Indo de cima para baixo e encontra o valor na célula A6.

Assim que encontra o valor, ela vai para a direita na segunda coluna e busca o valor nele.

Você pode usar a mesma fórmula para obter as notas de alguém em qualquer uma das matérias. Por exemplo, para encontrar as notas de Química de Maria, use a seguinte fórmula PROCV:

=PROCV(“Maria”;$A$3:$E$10;4;0)

No exemplo acima, o valor de pesquisa (nome do aluno) é inserido entre aspas duplas. Você também pode usar uma referência de célula que contém o valor de pesquisa. O benefício de usar uma referência de célula é que ela torna a fórmula dinâmica.

Por exemplo, se você tiver uma célula com o nome de um aluno e estiver buscando a pontuação do Mateus, o resultado será automaticamente atualizado quando você alterar o nome do aluno (conforme mostrado abaixo):

Se você inserir um valor de pesquisa que não seja encontrado na coluna mais à esquerda, ele retornará um erro #N/D.

Exemplo 2 – Consulta com dois critérios

No Exemplo 1, codificamos o valor da coluna. Assim, a fórmula sempre retornará a pontuação para Mateus, pois usamos 2 como o número do índice da coluna.

Mas e se você quiser tornar o valor PROCV e o número de índice da coluna dinâmicos? Por exemplo, conforme mostrado abaixo, você pode alterar o nome do aluno ou o nome da matéria e a fórmula PROCV busca a nota correspondente. Este é um exemplo de uma fórmula PROCV bidirecional ou simplesmente uma consulta com dois critérios.

Para criar essa fórmula de pesquisa bidirecional, você precisa tornar a coluna dinâmica também. Assim, quando um usuário muda de matéria, a fórmula seleciona automaticamente a coluna correta (coluna 2 no caso de Matemática, coluna 3 no caso de Física, assim por diante…).

Para fazer isso, será necessário usar a função CORRESP como o argumento da coluna. Abaixo está a fórmula de PROCV que fará isso:

=PROCV(G4;$A$3:$E$10;CORRESP(H3;$A$2:$E$2;0);0)

A fórmula acima usa CORRESP(H3;$A$2:$E$2;0);0) como o número da coluna. A função CORRESP leva o nome da matéria como o valor de pesquisa (em H3) e retorna sua posição em A2:E2. Portanto, se você usar CORRESP, ela retornará 2, pois CORRESP é encontrado em B2 (que é a segunda célula no intervalo da matriz especificada).

Exemplo 3 – Usando listas suspensas como valores de pesquisa

No exemplo anterior, tivemos que inserir manualmente os dados. Isso pode ser demorado e propenso a erros, principalmente se você tiver uma lista enorme com valores de pesquisa.

Uma ótima opção nesses casos é criar uma lista suspensa (menu dropdown) com valores de pesquisa (neste caso, pode ser nomes e matérias de alunos) e, em seguida, simplesmente selecionar o item desejado na lista.

Com base na seleção, a fórmula atualizará automaticamente o resultado. Algo como mostrado abaixo:

Esse recurso pode ser muito útil para a criação de um dashboard no Excel, já que você pode ter uma enorme quantidade de dados com centenas de alunos em back-end, mas o usuário final (digamos, um professor) pode rapidamente obter as notas de um aluno em uma matéria simplesmente fazendo as seleções na lista suspensa.

Como fazer isso:

A fórmula PROCV usada neste caso é a mesma usada no Exemplo 2.

=PROCV(G4;$A$3:$E$10;CORRESP(H3;$A$2:$E$2;0);0)

Os valores de pesquisa foram convertidos em listas suspensas. Aqui estão as etapas para criar a lista suspensa:

1. Selecione a célula na qual você deseja a lista suspensa. Neste exemplo, no G4, queremos os nomes dos alunos.
2. Acesse a guia Dados > Ferramentas de Dados > Validação de Dados.
3. Na caixa Diálogo de validação de dados, na guia Configurações, selecione Lista na lista suspensa Permitir.
Na fonte, selecione $A$3:$A$10
4. Clique OK.

Agora você terá a lista suspensa na célula G4. Da mesma forma, você pode criar uma lista suspensa em H3 para as matérias.

Exemplo 4 – Pesquisa com três critérios

No Exemplo 2, usamos uma tabela de pesquisa com notas para alunos em diferentes disciplinas. Este é um exemplo de uma pesquisa com dois critérios, pois usamos duas variáveis para buscar a pontuação (o nome do aluno e o nome da matéria).

Agora, suponha-se que em um ano, um aluno tenha três níveis diferentes de exames, Exame 1, Exame 2 e Exame Final.

Uma pesquisa com três critérios seria ideal para se obter as notas de um aluno para uma determinada matéria a partir do Exame especificado. Algo como mostrado abaixo:

No exemplo acima, a função PROCV pode pesquisar três tabelas diferentes (Exame 1, Exame 2 e Exame Final) e retornar a nota para o aluno especificado na matéria especificada.

Abaixo está a fórmula usada na célula H4:

=PROCV(G4;ESCOLHER(SE(H2=”Exame 1″;1;SE(H2=”Exame 2″;2;3));$A$3:$E$7;$A$11:$E$15;$A$19:$E$23);CORRESP(H3;$A$2:$E$2;0);0)

Essa fórmula usa a função ESCOLHER para garantir que a tabela correta seja selecionada na pesquisa. Vamos analisar essa parte da fórmula:

ESCOLHER(SE(H2=”Exame 1″;1;SE(H2=”Exame 2″;2;3));$A$3:$E$7;$A$11:$E$15;$A$19:$E$23)

O primeiro argumento da fórmula é SE(H2=”Exame 1″;1;SE(H2=”Exame 2″;2;3)), que verifica a célula H2 para ver a qual exame está sendo referido. Se for o Exame 1, ele retorná $A$3:$E$7, que contém as notas do Exame 1. Se for do Exame 2, ele retornará $A$11:$E$15, caso contrário, retornará $A$19:$E$23.

Fazer isso torna a matriz da tabela PROCV dinâmica e, portanto, faz dela uma pesquisa com três critérios.

Exemplo 5 – PROCV para obter o último valor de uma lista

A função PROCV também poder ser muito útil para se obter o último valor numérico de uma lista.

O maior número positivo que se pode usar no Excel é 9999999999999999E+307 . Isso também significa que o maior número de pesquisa na função PROCV também é o mesmo.

Por ser um número tão grande, usaremos ele para obter o último número em uma lista. Deste modo, suponha-se que você tenha um conjunto de dados (em A1:A14) como mostrado abaixo e você deseja obter o último número na lista.

Abaixo está a fórmula que você pode usar:

=PROCV(999999999999999+307;$A$1:$A$14;VERDADEIRO)

Note que a fórmula acima usa uma correspondência aproximada PROCV (observe o VERDADEIRO no final da fórmula, em vez de FALSO ou 0). Além disso, observe que a lista não precisa ser classificada para que essa fórmula de PROCV funcione.

Veja abaixo como funciona a função PROCV neste caso. Ela faz uma varredura na coluna de cima para baixo.

Se encontrar uma correspondência exata, ela retornará esse valor.
Se encontrar um valor maior que o valor de pesquisa, ele retornará o valor na célula acima dele.
Se o valor de pesquisa for maior que todos os valores da lista, ela retornará o último valor.

No exemplo acima, o terceiro cenário está no trabalho.

Como 9.99999999999999+307 é o maior número que pode ser usado no Excel, quando isso é usado como o valor de pesquisa, ele retorna o último número da lista.

Do mesmo modo, também é possível usar essa função para retornar o último item de texto da lista. Aqui está a fórmula que pode fazer isso:

=PROCV(“zzz”;$A$1:$A$8;1;VERDADEIRO)

A mesma lógica segue. O Excel examina todos os nomes e, como o zzz é considerado maior que qualquer nome / texto que comece com os alfabetos antes do zzz, ele retornará o último item da lista.

Exemplo 6: PROCV com caracteres curinga

O uso de caracteres curinga também merece fazer parte da lista com os melhores exemplos de PROCV no Excel.

Os caracteres curinga do Excel podem ser realmente úteis em muitas situações, inclusive no uso da função PROCV para realizar uma pesquisa parcial.

A pesquisa parcial é necessária quando se deseja procurar um valor em uma lista e não há uma correspondência exata. Por exemplo, suponha-se que você tenha um conjunto de dados como mostrado abaixo e deseja procurar a empresa ABC em uma lista, mas a lista tem ABC Ltd em vez de simplesmente ABC.

Neste caso, não é possível usar “ABC” como o valor de pesquisa, pois não existe correspondência exata na coluna A. A correspondência aproximada também levará a resultados errados, além de exigir que a lista seja classificada em ordem crescente.

No entanto, é possível usar um caractere curinga na função PROCV para obter a correspondência desejada.

Para este exemplo, utilizaremos a fórmula mostrada abaixo e arrastaremos para as demais células:

=PROCV(“*”&C2&”*”;$A$2:$A$8;1;FALSO)

Como esta fórmula funciona?

No exemplo acima, em vez de usarmos o valor de pesquisa como está, ele é concatenado em ambos os lados com o caractere curinga asterisco (*) – “*”&C2&”*”

Vale lembrar que um asterisco é um caractere curinga no Excel e pode representar qualquer número de caracteres.

Usando o asterisco em ambos os lados do valor de pesquisa informa ao Excel que ele precisa procurar por qualquer texto que contenha a palavra em C2. Pode ter qualquer número de caracteres antes ou depois do texto em C2.

Por exemplo, a célula C2 contém a palavra ABC, portanto, a função PROCV examinará os nomes no intervalor A2:A8 e procurará por ABC. Ela encontrará uma correspondência na célula A2, pois contém ABC na ABC Ltd. Não importa se existem caracteres à esquerda ou à direita da ABC. Deste que haja ABC em uma célula, isso será considerado uma correspondência.

Importante: A função PROCV sempre retorna o primeiro valor correspondente e pára de procurar. Então, se você tiver ABC Ltd. e ABC Corporation em uma lista, ele retornará o primeiro e ignorará o restante.

Exemplo 7: PROCV para remover espaços

Às vezes a função PROCV pode deixar alguns usuários loucos, pois é notável que existe um valor de pesquisa correspondente, no entanto, a função retorna retornando um erro.

Por exemplo, no caso abaixo, há uma correspondência (Mateus), mas a função PROCV ainda retorna um erro.

É notável que existe a correspondência que estamos buscando, mas o que não podemos notar a olho nu é que pode haver espaços no início ou no final do nome. Portanto, você tiver esses espaços adicionais antes, depois ou entre os valores de pesquisa, então você NÃO terá uma correspondência exata.

Esse problema é muito comum em casos onde o usuário importa dados de um banco de dados ou os obtém de outra pessoa. Esses espaços iniciais / finais tendem a se infiltrar. A solução aqui é a função ARRUMAR para remove quaisquer espaços iniciais ou finais ou espaços extras entre palavras.

Abaixo está a fórmula que lhe dará o resultado correto.

=PROCV(“Mateus”;ARRUMAR($A$2:$A$9);1;0)

Como essa é uma fórmula de matriz, será necessário usar as teclas CTRL + Shift + Enter em vez de apenas Enter.

Outra opção seria simplesmente tratar primeiro sua matriz de pesquisa com a função ARRUMAR para garantir que todos os espaços adicionais tenham desaparecido e, em seguida, use a função PROCV normalmente.

Exemplo 8: PROCV para pesquisa sensível a maiúsculas e minúsculas

Por padrão, os resultados de pesquisa da função PROCV não diferenciam letras maiúsculas de minúsculas. Por exemplo, se o valor pesquisa for MATEUS, Mateus ou mateus, será tudo igual para a função PROCV e deste modo, retornará o primeiro valor correspondente, independentemente do caso.

Mas se você quiser fazer uma pesquisa com distinção entre maiúsculas e minúsculas, precisará usar a função EXATO junto com a função PROCV. Veja o exemplo abaixo:

Como você pode notar no exemplo acima, existem três células com o mesmo nome (em A2, A4 e A5), mas diferenciadas entre si pelas letras maiúsculas e minúsculas. À direita, temos os três nomes (Mateus, MATEUS e mateus), juntamente com suas respectivas notas.

Contudo a função PROCV sozinha não é capaz de manipular valores de pesquisa com diferenciação de maiúsculas e minúsculas. Neste exemplo acima, ela sempre retornaria 38, que é a pontuação de Mateus em A2.

Para torná-lo sensível a maiúsculas e minúsculas, precisamos usar uma coluna auxiliar (como mostrado abaixo):

Para obter os valores na coluna auxiliar, use a função =LIN(). Ele simplesmente obterá o número da linha na célula.

Depois de ter a coluna auxiliar, aqui está a fórmula que fornecerá o resultado da pesquisa com diferenciação de maiúsculas e minúsculas.

=PROCV(MÁXIMO(EXATO(E2;$A$2:$A$9)*(LIN($A$2:$A$9)));$B$2:$C$9;2;0)

Agora vamos analisar e entender o que isso faz:

EXATO(E2;$A$2:$A$9) – Esta parte compara o valor de pesquisa em E2 com todos os valores em A2:A9. Ela retorna uma matriz de VERDADEIROs / FALSOs onde VERDADEIRO é retornado quando há uma correspondência exata. Neste caso, retornará a seguinte matriz: {VERDADEIRO; FALSO; FALSO; FALSO; FALSO; FALSO; FALSO; FALSO}.
EXATO(E2;$A$2:$A$9)*(LIN($A$2:$A$9) – Esta parte multiplica a matriz de VERDADEIROs / FALSOs com o número da linha. Onde quer que haja um VERDADEIRO, ela irá fornece o número da linha , senão retornará 0. Neste caso, retornará {2; 0; 0; 0; 0; 0; 0; 0}.
MÁXIMO(EXATO(E2;$A$2:$A$9)*(LIN($A$2:$A$9))) – Esta parte retorna o valor máximo da matriz de números. Nesse caso, retornaria 2 (que é o número da linha onde há uma correspondência exata).
Agora, simplesmente usamos esse número como o valor de pesquisa e usamos a matriz de pesquisa como B2: C9

Importante: Como esta é uma fórmula de matriz, use Control + Shift + Enter em vez de apenas inserir.

Exemplo 9: PROCV com vários critérios

A função PROCV em sua forma básica, pode procurar por um valor de pesquisa e retornar o valor correspondente da linha especificada. Mas muitas vezes há uma necessidade de usar o PROCV no Excel com vários critérios.

Suponha-se que você tenha dados com o nome dos alunos, o tipo de exame e a nota de matemática (conforme mostrado abaixo):

Usar a função PROCV para obter as notas de matemática de cada aluno para os respectivos exames pode ser um desafio.

Por exemplo, se você tentar usar a função PROCV com Mateus como o valor de pesquisa, ela sempre retornará 91, que é a pontuação da primeira ocorrência de Mateus na lista. Para obter a pontuação de Mateus para cada tipo de exame (Exame 1, Exame 2 e Exame Final), você precisa criar um valor de pesquisa exclusivo.

Isso pode ser feito usando a coluna auxiliar. O primeiro passo é inserir uma coluna auxiliar à esquerda das pontuações.

Agora, para criar um qualificador exclusivo para cada instância do nome, use a seguinte fórmula em C2: =A2&”|”&B2.

Copie essa fórmula para todas as células na coluna auxiliar. Isso irá criar valores de pesquisa exclusivos para cada instância de um nome (conforme mostrado abaixo):

Com esse simples truque não haverá mais repetições, uma vez que o nome é combinado com o nível de exame. Isso facilita, pois agora você pode usar os valores da coluna de ajuda como valores de pesquisa.

Abaixo temos a fórmula que dará o resultado em G3:I8.

=PROCV($F3&”|”&G$2;$C$2:$D$16;2;0)

Aqui combinamos o nome do aluno e o tipos de exame para obter o valor de pesquisado, e usamos esse valor de pesquisa e o verificamos na coluna auxiliar para obter o registro correspondente.

Note: No exemplo acima, usamos | como o separador ao juntar texto na coluna auxiliar. Em algumas condições excepcionalmente raras (mas possíveis), você pode ter dois critérios diferentes, mas acaba dando o mesmo resultado quando combinado. Aqui está um exemplo:

Observe que enquanto A2 e A3 são diferentes e B2 e B3 são diferentes, as combinações acabam sendo as mesmas na coluna C. Mas se usarmos um separador, então a combinação será diferente (D2 e D3).

Exemplo 10: Como lidar com erros na função PROCV

Por fim, outro caso que merece entrar na nossa lista de exemplos de PROCV é o uso com a função SEERRO.

Como se sabe, a função PROCV retorna um erro quando não consegue encontrar o valor de pesquisa especificado. Você pode não querer que o valor de erro feio atrapalhe a estética de seus dados caso o PROCV não encontre um valor.

E a boa notícia é que você pode facilmente remover os valores de erro com qualquer texto, como “Não disponível” ou “Não encontrado”.

Por exemplo, no exemplo abaixo, quando você tenta encontrar a nota de Bruno na lista, o Excel retorna um erro, pois o nome de Bruno não está na lista.

Para remover esse erro e substituí-lo por algo significativo, coloque sua função PROCV dentro da função SEERRO.

=SEERRO(PROCV(D2;A2:B6;2;0);”Não encontrado”)

A função SEERRO verifica se o valor retornado pelo primeiro argumento (que é a função PROCV neste caso) é um erro ou não. Se não for um erro, ele retorna o valor pela função PROCV, senão retorna Não encontrado.

Note: A função SEERRO está disponível no Excel 2007 em diante. Se você estiver usando versões anteriores, use a seguinte função:

=SE(ÉERROS(PROCV(D2;$A$2:$B$7;2;0));”Não encontrado”;(PROCV(D2;$A$2:$B$7;2;0))

Baixe aqui a Planilha com os Exemplos de PROCV usados neste artigo

Confira também as seguintes dicas de Excel:

E então, o que achou da lista de exemplos de PROCV no Excel? Deixe o seu comentário abaixo, gostaríamos muito de conhecer a sua opinião! Para conferir mais dicas de Excel, continue acompanhando o Excel Easy!