Função CORRESP no Excel: Como usar?

Quer aprender a usar a função CORRESP no Excel? Então você está no lugar certo!

No Excel, existem diversas funções de pesquisa que podem ajudá-lo a encontrar um determinado valor em um intervalo de células, sendo a função CORRESP uma dessas funções.

Basicamente, essa função identifica uma posição relativa de um item em um intervalo de células. No entanto, a função CORRESP pode fazer muito mais do que sua funcionalidade básica.

Este tutorial explicará como usar a função CORRESP no Excel com exemplos de fórmulas práticas. Além disso, mostraremos também como melhorar suas fórmulas de pesquisa usando uma fórmula dinâmica com PROCV e CORRESP. Confira!

Função CORRESP no Excel – sintaxe e usos básicos

A função CORRESP procura por um valor especificado em um intervalo de células e retorna a posição relativa desse valor.

A sintaxe da função CORRESP é:

CORRESP(valor_proc; matriz_proc; [tipo_corresp])

Onde:

valor_proc: Argumento obrigatório. Representa o valor que você deseja encontrar e pode ser um valor numérico, de texto ou lógico, ou uma referência de célula.

matriz_proc: Argumento obrigatório. Representa o intervalo de células para pesquisar.

tipo_corresp: Argumento opcional. Define o tipo de correspondência e pode ser um desses valores: 1, 0, -1. O argumento tipo_corresp definido como 0 retorna apenas a correspondência exata, enquanto os outros dois tipos permitem a correspondência aproximada.

• 1 ou omitido (padrão) – encontre o maior valor na matriz de pesquisa que seja menor ou igual ao valor de pesquisa. Requer a classificação da matriz de pesquisa em ordem crescente, do menor para o maior ou de A para Z.
• 0 – encontra o primeiro valor na matriz que é exatamente igual ao valor de pesquisa. Nenhuma classificação é necessária.
• -1 – encontra o menor valor na matriz que seja maior ou igual ao valor de pesquisa. A matriz de pesquisa deve ser classificada em ordem decrescente, da maior para a menor ou de Z para A.

Exemplo:

Para melhor compreensão da função CORRESP no Excel, vamos criar uma fórmula simples com base nesses dados: os nomes dos alunos na coluna A e as pontuações dos exames na coluna B, classificadas de maior para menor. Para descobrir onde um aluno específico (por exemplo, Melissa ) está entre outros, use esta fórmula simples:

=CORRESP("Melissa";A2:A8;0)

Opcionalmente, você pode colocar o valor de pesquisa em alguma célula (E3 neste exemplo) e fazer referência a essa célula na sua fórmula de Correspondência do Excel:

=CORRESP(D3;A2:A8;0)

Como podemos observar na imagem acima, os nomes dos alunos são inseridos em uma ordem aleatória e, portanto, definimos o argumento tipo_corresp como 0 (correspondência exata), porque somente esse tipo de correspondência não exige valores de classificação na matriz de pesquisa. Tecnicamente, a fórmula CORRESP retorna a posição relativa de Melissa no intervalo que está sendo pesquisado.

No entanto, o fato de os resultados estarem ordenados do maior para o menor, ele também nos diz que Melissa tem a 6º melhor pontuação entre todos os alunos.

Detalhes que você precisa saber:

Como você acabou de ver, usar a função CORRESP no Excel é fácil. No entanto, como é o caso de praticamente qualquer função do Excel, existem algumas especificidades que você deve conhecer:

• A função CORRESP retorna a posição relativa do valor de pesquisa na matriz, não o valor em si.
• A CORRESP não faz distinção entre maiúsculas e minúsculas, ou seja, ela não faz distinção entre caracteres minúsculos e maiúsculos ao lidar com valores de texto.
• Se a matriz de pesquisa contiver várias ocorrências do valor de pesquisa, a posição do primeiro valor será retornada.
• Caso o valor de pesquisa não seja encontrado na matriz de pesquisa, o erro #N/D será retornado.

Como usar a função CORRESP no Excel – exemplos práticos

Agora que você conhece o uso básico da função CORRESP no Excel, confira a seguir alguns exemplos de fórmulas que vão além do básico.

Exemplo 1: Função CORRESP com caracteres curinga

Como muitas outras funções do Excel, a função CORRESP também aceita os seguintes caracteres curinga:

• Ponto de interrogação (?) – substitui qualquer caractere único
• Asterisco (*) – substitui qualquer sequência de caracteres

Importante: Os caracteres curinga só podem ser usados ​​em fórmulas de correspondência com tipo_corresp definido como 0.

Usar a função CORRESP com caracteres curingas pode ser útil em situações em que você não deseja corresponder a cadeia de texto inteira, mas apenas alguns caracteres ou parte dela. Para melhor compreensão, considere o seguinte exemplo.

Suponha que você tenha uma lista de revendedores regionais e seus respectivos números de vendas do último mês. Você deseja encontrar uma posição relativa de um determinado revendedor na lista (classificado pelos valores de vendas em ordem decrescente), mas não consegue lembrar exatamente o nome dele, embora lembre de alguns primeiros caracteres.

Supondo que os nomes de revendedor estão no intervalo A2:A11 e você está procurando o nome que começa com “Car”, a fórmula será a seguinte:

=CORRESP("car*";A2:A11;0)

Para tornar nossa fórmula mais prática, você pode digitar o valor de pesquisa em alguma célula (E1 neste exemplo) e concatenar essa célula com o caractere curinga, assim:

=CORRESP(E1&"*";A2:A11;0)

Como mostrado na imagem abaixo, a fórmula retornará 2, que é a posição de “Carlos”:

Para substituir apenas um caractere no valor de pesquisa, use o “?” como operador de curinga, assim:

=CORRESP("E?a";A2:A11;0)

A fórmula acima corresponderá ao nome “Eva” e quando executada, retornará a posição 9.

Exemplo 2: CORRESP com diferenciação de maiúsculas de minúsculas

Conforme mencionado anteriormente, a função CORRESP no Excel não distingue caracteres maiúsculos e minúsculos. No entanto, é possível combina a função CORRESP com a função EXATO para que haja distinção entre maiúsculas e minúsculas.

Basicamente  fórmula que diferencia maiúsculas de minúsculas é:

=CORRESP(VERDADEIRO;EXATO(matriz de pesquisa;valor de pesquisa);0)

A fórmula funciona com a seguinte lógica:

• A função EXATO compara o valor de pesquisa com cada elemento da matriz de pesquisa. Se as células comparadas forem exatamente iguais, a função retornará VERDADEIRO, ou FALSO caso contrário.
• E, em seguida, a função CORRESP compara VERDADEIRO (que é seu valor_proc) com cada valor na matriz retornada pelo EXATO e retorna a posição da primeira correspondência.

Observe que esta é uma fórmula de matriz, ou seja, será necessário pressionar Ctrl + Shift + Enter para ser concluída corretamente.

Supondo que seu valor de pesquisa esteja na célula E1 e a matriz de pesquisa seja A2:A9, a fórmula é a seguinte:

=CORRESP(VERDADEIRO;EXATO(A2:A9;E1);0)

A imagem abaixo mostra um exemplo de como funciona a função CORRESP com diferenciação de maiúsculas e minúsculas no Excel:

Veja também: ÍNDICE e CORRESP no Excel: A Alternativa para o PROCV

Como usar a função PROCV com CORRESP?

Se você chegou até aqui, pressupõe-se que você já tenha algum conhecimento básico da função PROCV no Excel e que provavelmente encontrou diversas limitações e esteja procurando uma alternativa mais robusta.

Um dos inconvenientes da função PROCV é que ela deixa de funcionar após inserir ou excluir uma coluna em uma tabela de pesquisa. Isso acontece porque a função PROCV extrai um valor correspondente com base no número da coluna de retorno que você especifica (número do índice). Como o número do índice é “codificado” na fórmula, o Excel não consegue ajustá-lo quando uma nova coluna é adicionada ou excluída da tabela.

Por outro lado, a função CORRESP no Excel lida com uma posição relativa de um valor de pesquisa, o que a torna um ajuste perfeito para o argumento núm_índice_coluna na função PROCV. Em outras palavras, em vez de especificar a coluna de retorno como um número estático, basta usar CORRESP para obter a posição atual dessa coluna.

Observe o exemplo abaixo onde temos as notas de Português e Matemática para os alunos de uma sala. Neste exemplo, estamos usando a função PROCV para obter a nota de Matemática da aluna Laura.

A função PROCV neste caso funciona bem. Mas se você excluir ou adicionar uma nova coluna em sua tabela, terá como resultado o erro #REF!, ou seja, a função perdeu a sua referência de busca.

Para evitar que isso aconteça, podemos tornar a função PROCV mais dinâmica, incluindo a função CORRESP.

=PROCV($F$1;$A$1:$C$8;CORRESP($E$2;$A$1:$C$1;0);FALSO)

Onde:

• E2 é o valor de pesquisa, que é exatamente igual ao nome da coluna de retorno, ou seja, a coluna da qual você deseja extrair um valor (Nota Matemática neste exemplo).
• A1:C1 é a matriz de pesquisa que contém os cabeçalhos da tabela.

Nota: De maneira semelhante, também é possível usar a função CORRESP no Excel para otimizar a função PROCH.

Baixe aqui planilha com os exemplos apresentados neste tutorial.

Confira também as seguintes dicas de Excel:

• Função ÍNDICE no Excel: Como usar?
• 10 exemplos de PROCV para usuários iniciantes e avançados
• Função DESLOC e CORRESP no Excel em 5 minutos

E então, o que achou do artigo sobre a função CORRESP no Excel ? Deixe o seu comentário abaixo, gostaríamos muito de conhecer a sua opinião! Para conferir mais dicas de Excel, continue acompanhando o Excel Easy!